Outlook-Baglanti-Detaylari-ve-Sorun-Giderme-ipucu

Bu yazıda Active Directory ortamında oturum açan kullanıcıya oturum açtığı tarih saat ve bilgisayar adının e-posta olarak gönderilmesinden bahsedeceğim. İlk bakışta gereksiz gibi görünse de örneğin bir personel izinliyken cep telefonuna kullanıcı adınız ile PC001 bilgisayarında oturum açılmıştır şeklinde bir e-posta gelmesi kullanıcının şifresini bilen başka birinin o personel adına oturum açtığından haberdar olmasını sağlayacaktır.

Başlayalım.

Bunun için GPO ile kullanıcılara Logon Script uygulayacağız. User Configuration altında logon script uygulayacağız çünkü scriptin kullanıcı oturum açtıktan hemen sonra çalışması gerekli.

Yeni bir GPO oluşturup düzenleyelim ve aşağıdaki scrpti logininfo.vbs gibi bir isimle kaydedip logon script olarak uygulayın. Burada logon scriptin Nasil uygulandığına girmeyeceğim. Bununla ilgili Group Policy Object (GPO) ile Firefox Sertifika Yüklenmesi Nasil Yapılır? isimli yazıma bakabilirsiniz.

'------------------------------------------------------------------------Tanımlamalar Başlangıç-----------------------------------
Dim CompName, tarih, saat,strFullName,strEmail,strCorpEmail,EmailMessage, ObjMessage
'------------------------------------------------------------------------Tanımlamalar Bitiş---------------------------------------
On Error Resume Next

'----------------------------------------------------------------------------Atamalar Başlangıç-----------------------------------
'AD den kullanıcı ve bilgisayar bilgilerini oku
Set objSysInfo = CreateObject("ADSystemInfo")
Set objUser    = GetObject("LDAP://" & objSysInfo.Username)
Set objComputer = GetObject("LDAP://" & objSysInfo.ComputerName)
Set WshNetwork = WScript.CreateObject("WScript.Network")
CompName= WshNetwork.Computername
'--------------------------------------------------------------
strFullName = objUser.displayname
strEmail    = objuser.emailaddress
strUserName = objUser.samaccountname
tarih = Date()
saat = time()

'-----------------------------------------------------------------------------Atamalar Bitiş----------------



'-------------------------------------------------------------Login Bilgi Maili Gönderme Başlangıç-----------------------
On Error Resume Next
EmailMessage = "<b>" & "Sayın " & strFullName & "<br>" & strUserName & "</b>" & " kullanıcı hesabı ile <b>"&  Compname & "</b> isimli bilgisayarda <b>" & tarih & "</b> tarihinde " & " saat <b>" & saat & "</b> de " & "oturum açılmıştır.<br> Bu mail bilginiz dışında oturum açıldığını tespit edebilmeniz için gönderilmiştir.<br>Bilginiz dışında oturum açıldığını farketmeniz durumunda ivedilikle http://mail.astronur.com adresinden den şifrenizi değiştirip Bilgi İşlem Personelinize bilgi veriniz.<br><br><br> <b>Bilgi İşlem Müdürlüğü <br><br>"

EmailMessage=replace(EmailMessage,"İ","&#304;")
EmailMessage=Replace(EmailMessage,"ı","&#305;")
EmailMessage=Replace(EmailMessage,"Ö","&#214;")
EmailMessage=Replace(EmailMessage,"ö","&#246;")
EmailMessage=Replace(EmailMessage,"Ü","&#220;")
EmailMessage=Replace(EmailMessage,"ü","&#252;")
EmailMessage=Replace(EmailMessage,"Ç","&#252;")
EmailMessage=Replace(EmailMessage,"ç","&#231;")
EmailMessage=Replace(EmailMessage,"Ğ","&#286;")
EmailMessage=Replace(EmailMessage,"ğ","&#287;")
EmailMessage=Replace(EmailMessage,"Ş","&#x15e;")
EmailMessage=Replace(EmailMessage,"ş","&#351;")



SendEmail EmailMessage


Sub SendEmail(EmailMessage)
	Const cdoSendUsingPickup = 1 'Send message using the local SMTP service pickup directory. 
	Const cdoSendUsingPort = 2 'Send the message using the network (SMTP over the network). 
	Const cdoAnonymous = 0 'Do not authenticate
	Const cdoBasic = 1 'basic (clear-text) authentication
	Const cdoNTLM = 2 'NTLM
	
	Set objMessage = CreateObject("CDO.Message") 
	objMessage.Subject = "Oturum Açma Bilgisi"
	objMessage.Subject=Replace(objMessage.Subject,"ç",chrW(231))
	objMessage.From = "uyari@astronur.com"
	objMessage.To = strEmail

	objMessage.HtmlBody = EMailMessage

	
	'==This section provides the configuration information for the remote SMTP server.
	objMessage.Configuration.Fields.Item _
	("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2 

	'Name or IP of Remote SMTP Server
	objMessage.Configuration.Fields.Item _
	("http://schemas.microsoft.com/cdo/configuration/smtpserver") = "MAIL_SUNUCU_IP"

	'Type of authentication, NONE, Basic (Base64 encoded), NTLM
	objMessage.Configuration.Fields.Item _
	("http://schemas.microsoft.com/cdo/configuration/smtpauthenticate") = cdoBasic

	'Your UserID on the SMTP server
	objMessage.Configuration.Fields.Item _
	("http://schemas.microsoft.com/cdo/configuration/sendusername") = "astronur\SAMACCOUNTNAME"

	'Your password on the SMTP server
	objMessage.Configuration.Fields.Item _
	("http://schemas.microsoft.com/cdo/configuration/sendpassword") = "PAROLA"

	'Server port (typically 25)
	objMessage.Configuration.Fields.Item _
	("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = 25 

	'Use SSL for the connection (False or True)
	objMessage.Configuration.Fields.Item _
	("http://schemas.microsoft.com/cdo/configuration/smtpusessl") = False

	'Connection Timeout in seconds (the maximum time CDO will try to establish a connection to the SMTP server)
	objMessage.Configuration.Fields.Item _
	("http://schemas.microsoft.com/cdo/configuration/smtpconnectiontimeout") = 60

	objMessage.Configuration.Fields.Update

	'==End remote SMTP server configuration section==

	objMessage.Send

	Set ObjMessage = Nothing
End Sub
On Error GoTo 0
'-------------------------------------------------------------Login Bilgi Maili Gönderme Bitiş---------------------------

Scriptin içinde mail sunucusuna bağlanmak için gerekli kullanıcı adı ve şifreyi clear text yazmak gerekiyor. Bunu gizlemenin yolunu biliyorsanız yorumdan yazarsanız güncellerim. Ayrıca sarı ile belirtilen satırları kendinize göre güncellemeniz gerekmektedir.

Scripti GPO ile uyguladığınızda kullanıcılar bilgisayarlarında oturum açtıklarında kendilerine aşağıdaki gibi mail gelecektir.

oturum-acan-kullaniciya-oturum-bilgilerinin-mail-olarak-iletilmesi
Örnek Mail – Remi büyültmek için tıklayın

 

Leave a Reply

Instagram

[instagram-feed num=6 cols=6 showfollow=false showheader=false showbutton=false showfollow=false]